(in-package #:parser)

(defun run (p input)
  (let ((r (funcall p input)))
    (if (parsing-p r)
      (parsing-tree r)
      (input::generate-report (failure-place r) (failure-message r)))))

(defstruct parsing
  tree
  left)

(defstruct failure
  place
  message)

(defstruct (normal-failure (:include failure)))

(defstruct (critical-failure (:include failure)))

(defun new (tree)
  (lambda (input)
    (make-parsing :tree tree :left input)))

(defun bind (p f)
  (lambda (input)
    (let ((r (funcall p input)))
      (if (parsing-p r)
        (funcall (funcall f (parsing-tree r)) (parsing-left r))
        r))))

(defun fail (&optional (message "Unknown error."))
  (lambda (input)
    (make-critical-failure :place input :message message)))

(defun either (first-parser second-parser &rest other-parsers)
  (lambda (input)
    (labels ((either-rec (body)
                         (if (cdr body)
                           (let ((r (funcall (car body) input)))
                             (if (normal-failure-p r)
                               (either-rec (cdr body))
                               r))
                           (funcall (car body) input))))
      (either-rec (cons first-parser (cons second-parser other-parsers))))))

(defun unit (&optional (predicate #'characterp))
  (lambda (input)
    (if (input::has-data? input)
      (let ((c (input::peek-1 input)))
        (if (funcall predicate c)
          (make-parsing :tree c :left (input::advance input))
          (make-normal-failure :place input :message "Predicate not satisfied.")))
      (make-normal-failure :place input :message "Reached end of input."))))

(defun literal (predicate)
  (lambda (input)
    (if (input::has-data? input (length predicate))
      (let ((str (input::peek-n input (length predicate))))
        (if (string= predicate str)
          (make-parsing :tree str :left (input::advance input (length predicate)))
          (make-normal-failure :place input :message "Predicate not satisfied.")))
      (make-normal-failure :place input :message "Reached end of input."))))

(defmacro comp (bindings &body body)
  (if (null bindings)
    `(new (progn ,@body))
    (let ((v (first (car bindings)))
          (p (second (car bindings))))
      (if (eq v '_)
        `(bind ,p (lambda () (comp ,(cdr bindings) ,@body)))
        `(bind ,p (lambda (,v) (comp ,(cdr bindings) ,@body)))))))

(defparameter nothing
  (new nil))

(defun optional (p)
  (either p nothing))

(defun zero-or-more (p)
  (either (comp ((x p)
                 (xs (zero-or-more p)))
            (cons x xs))
          nothing))

(defun one-or-more (p)
  (comp ((x p)
         (xs (zero-or-more p)))
    (cons x xs)))

(defun separated-list (p separator)
  (comp ((v p)
         (sep (optional (the-char separator)))
         (vn (if sep
               (either (separated-list p separator)
                       (fail "Value expected."))
               nothing)))
    (cons v vn)))