(in-package #:monparser)

(defun parse-string (p input)
  (let ((result (funcall p (from-string input))))
    (if (parsing-p result)
      (parsing-tree result)
      result)))

(defun parse-file (p input)
  (let ((result (funcall p (from-file input))))
    (if (parsing-p result)
      (parsing-tree result)
      result)))

(defstruct parsing
  tree
  left)

(defstruct failure
  place
  message)

(defmethod print-object ((obj failure) stream)
  (let ((file (file (failure-place obj))))
    (if file
      (multiple-value-bind (line column) (line-and-column (failure-place obj))
        (format stream "~a:~a:~a: ~a" line column file (failure-message obj)))
      (format stream "~a: ~a" (cursor (failure-place obj)) (failure-message obj)))))

(defun new (tree)
  (lambda (input &optional lazy)
    (declare (ignore lazy))
    (make-parsing :tree tree :left input)))

(defun bind-with-input (p f)
  (lambda (input &optional lazy)
    (let ((r (funcall p input)))
      (if (parsing-p r)
        (if lazy
          (lambda (ignored-input &optional lazy)
            (declare (ignore ignored-input))
            (funcall (funcall f (parsing-tree r) input) (parsing-left r) lazy))
          (funcall (funcall f (parsing-tree r) input) (parsing-left r)))
        r))))

(defun bind (p f)
  (lambda (input &optional lazy)
    (let ((r (funcall p input)))
      (if (parsing-p r)
        (if lazy
          (lambda (ignored-input &optional lazy)
            (declare (ignore ignored-input))
            (funcall (funcall f (parsing-tree r)) (parsing-left r) lazy))
          (funcall (funcall f (parsing-tree r)) (parsing-left r)))
        r))))

(defun discarding-bind (p f)
  (lambda (input &optional lazy)
    (let ((r (funcall p input)))
      (if (parsing-p r)
        (if lazy
          (lambda (ignored-input &optional lazy)
            (declare (ignore ignored-input))
            (funcall (funcall f) (parsing-left r) lazy))
          (funcall (funcall f) (parsing-left r)))
        r))))

(defmacro comp (bindings &body body)
  (if (null bindings)
    `(new (progn ,@body))
    (let ((v (first (car bindings)))
          (p (second (car bindings))))
      (if (eq 'symbol (type-of v))
        (if (string= (symbol-name v) "_")
          `(discarding-bind ,p (lambda () (comp ,(cdr bindings) ,@body)))
          `(bind ,p (lambda (,v) (comp ,(cdr bindings) ,@body))))
        (if (and (eq 'cons (type-of v))
                 (eq 'symbol (type-of (car v)))
                 (eq 'symbol (type-of (cdr v))))
          `(bind-with-input ,p (lambda (,(car v) ,(cdr v)) (comp ,(cdr bindings) ,@body)))
          (error "Binding name/(name,input) must be either a symbol or a cons of symbols."))))))

(defun one-of (first-parser second-parser &rest other-parsers)
  (lambda (input &optional lazy)
    (declare (ignore lazy))
    (labels ((one-of-rec (parsers)
                         (let ((intermediate-parsers '())
                               (result (make-failure :place input
                                                     :message "Exausted options.")))
                           (dolist (p parsers)
                             (let ((r (funcall p input (> (length parsers) 1))))
                               (cond ((functionp r)
                                      (push r intermediate-parsers))
                                     ((parsing-p r)
                                      (setf result r)))))
                           (if intermediate-parsers
                             (one-of-rec intermediate-parsers)
                             result))))
      (one-of-rec (cons first-parser (cons second-parser other-parsers))))))

(defmacro unit (&optional predicate)
  (cond ((null predicate)
         (setf predicate '(characterp it)))
        ((symbolp predicate)
         (setf predicate `(,predicate it)))
        ((characterp predicate)
         (setf predicate `(char-equal ,predicate it)))
        (t (setf predicate
                 (nsubst-if 'it
                            (lambda (x)
                              (and (symbolp x)
                                   (string-equal (symbol-name x) "IT"))) predicate))))
  `(lambda (input &optional lazy)
     (declare (ignore lazy))
     (if (has-data? input)
       (let ((it (peek input)))
         (if ,predicate
           (make-parsing :tree it :left (advance input))
           (make-failure :place input
                         :message (format nil "Expected: ~a, Got: ~a" ',predicate it))))
       (make-failure :place input :message "Reached end of input."))))

(defun literal (target)
  (lambda (input &optional lazy)
    (declare (ignore lazy))
    (if (has-data? input)
      (if (prefix? target input)
        (make-parsing :tree target :left (advance input (length target)))
        (make-failure :place input :message "Predicate not satisfied."))
      (make-failure :place input :message "Reached end of input."))))

(defparameter nothing
  (new nil))

(defun optional (p)
  (one-of p nothing))

(defun many (p)
  (comp ((x p)
         (xs (optional (many p))))
        (cons x xs)))

(defun repeat (p min &optional (max 0))
  (if (> min 0)
    (comp ((x p)
           (xs (repeat p (1- min) (1- max))))
          (cons x xs))
    (if (> max 0)
      (comp ((x (optional p))
             (xs (repeat p 0 (if x (1- max) 0))))
            (if x (cons x xs) x))
      nothing)))

(defun whitespace? (x)
  (some (lambda (y) (char= x y)) '(#\Space #\Newline #\Tab)))

(defparameter whitespace
  (comp ((_ (optional (many (unit whitespace?)))))
        nil))

(defun separated-list (p separator &key include-separator)
  (comp ((v p)
         (sep (optional separator))
         (vn (if sep
               (crit (separated-list p separator))
               nothing)))
        (if include-separator
          (cons v (cons sep vn))
          (cons v vn))))