(in-package #:input)

(defstruct input
  (cursor 0)
  (file nil :read-only t)
  (data nil :read-only t))

(defun has-data? (input &optional (window-size 1))
  (<= (+ window-size (input-cursor input))
      (length (input-data input))))

(defun prefix? (target input)
  (string= target (input-data input) :start2 (input-cursor input) :end2 (+ (input-cursor input) (length target))))

(defun peek (input)
  (char (input-data input)
        (input-cursor input)))

(defun advance (input &optional (amount 1))
  (let ((new-input (copy-structure input)))
    (incf (input-cursor new-input) amount)
    new-input))

(declaim (ftype (function (simple-string) (values input &optional)) from-string))
(defun from-string (str)
  (make-input :data str))

(declaim (ftype (function (simple-string) (values input &optional)) from-file))
(defun from-file (filename)
  (make-input :file filename :data (str:read-file filename)))

(defun generate-report (input message)
  (let ((line 1) (column 1))
    (dotimes (i (input-cursor input))
      (let ((c (char (input-data input) i)))
        (case c
          (#\Newline
           (incf line)
           (setf column 1))
          (t (incf column)))))
    (if (input-file input)
      (format nil "~a:~a:~a: ~a" (input-file input) line column message)
      (format nil "~a:~a: ~a" line column message))))